///////////////////////////////////////////////////////////////////////////////
//                                                                           //
//                      (c)  Carlos Tricas 2003                              //
//                                                                           //
//                 carlos.tricas@mundosimaginados.com                        //
//                                                                           //
//                      www.mundosimaginados.com                             //
//                                                                           //
///////////////////////////////////////////////////////////////////////////////
//                                                                           //
//      Fichero: selec04.POV                                                 //
//                                                                           //
//      Nombre: ELIPSIS                                                      //
//                                                                           //
//      03/03                                                                //
//                                                                           //
///////////////////////////////////////////////////////////////////////////////  
//                                                                           //
// Descripción: Diseño formado por cilindros que parten del centro de        //
//              coordenadas del plano X,Z. La coordenada y de los extremos   //
//              cambia la altura mediante funciones armónicas desfasadas.    //
//                                                                           //
//              El nombre surge por el recuerdo que me produce el diseño de  //
//              la imaginería religiosa. Al verlo me recordó a los rayos que //
//              salen de detrás de algunos santos en las iglesias.           //
//              Y como el santo no está, pues eso...                         //
//                                                                           //
//                                                                           //
///////////////////////////////////////////////////////////////////////////////  
  




#include "colors.inc"

background {White}

camera {
	perspective
	location <0,20,-15>
	look_at <3,0,-3>
 	angle 50
        }


light_source	{ 
		< 0,20,-15> 
		White
		}





#declare fin = 2*pi;            // Ángulo a recorrer (una vuelta = 360º = 2*pi radianes).
#declare paso = pi/60 ;         // Ángulo girado en cada paso del bucle.   
#declare amplitud_centro = 2;   // Amplitud del recorrido del mov. armónico en el eje y.
#declare factor_centro = 3;     // Factor frecuencia desplazamiento en el eje y en el extremo del cilindro que está en el centro.
#declare radio_objeto = 50;     // Longitud de los cilindros.
#declare amplitud_extremo = 6;  // Amplitud del recorrido del mov. armónico en el eje y.
#declare factor_extremo = 10;   // Factor frecuencia desplazamiento en el eje y en el extremo de cilindro contrario al centro.
#declare radio_cilindro =  .25; // Radio de cada uno de los cilindros.
#declare n=0;                   // Contador.

#while (n<fin)
	cylinder{
		<0,
		 amplitud_centro*cos(n * factor_centro),
		 0>,     
		
		<radio_objeto*sin(n),
		 amplitud_extremo*sin(n * factor_extremo),
		 radio_objeto*cos(n)>,
		 radio_cilindro                                                        
		
		texture	{ 
		        pigment {White}
                        }
		                 
		}
		
		
	#declare n=n+paso	;


#end